• [1]
• [2]
• [3] [4]
• [5]
• [6]

Le développement manuel de grammaire à large couverture pose d'importants problèmes de maintenance, en particulier dus à la taille des grammaires et à la complexité des structures grammaticales.

Une première solution est d'oublier le coté manuel et de s'orienter vers l'extraction de grammaires stochastiques à partir de treebank (le gros du travail étant reporté sur la constitution du treebank). C'est la tendance actuelle mais conduit à des grammaires qui ne sont pas véritablement compréhensibles par des humains et qui ne peuvent être directement modifiées ou étendues.

Une autre approche, initiée dans les années 90 et début des années 2000, consiste à s'appuyer sur des descriptions modulaires et haut-niveau des phénomènes syntaxiques, sous forme de méta-grammaires. Plutôt que de devoir écrire des structures syntaxiques complètes, qui peuvent déjà mettre en œuvre plusieurs phénomènes syntaxiques (comme un sujet et un objet dans le cadre d'un verbe à la voie active), une méta-grammaire permet de décrire d'une part la notion de sujet (avec ses divers raffinement), la notion d'objet, la notion de verbe à la voie active, ..... Ces divers notions sont exprimées sous forme de contraintes regroupées en classes. Une classe peut hériter de classes parentes, ce qui permet de raffiner progressivement une notion. Les classes sont également combinables, et à partir de certaines de ces classes combinées dont les contraintes accumulées sont satisfiables, il est possible de produire des structures grammaticales complètes pour un formalisme cible donné comme les TAGs ou les LFGs.

Les diverses versions des méta-grammaires diffèrent sur les types de contraintes autorisées, les types d'héritages, les mécanismes de combinaison des classes, et la production des structures grammaticales. Elles partagent cependant beaucoup de points communs.

FRMG s'appuie sur une variante de méta-grammaire développée en interne, orientée pour la production de grammaires TAG. Les classes et contraintes peuvent s'écrire sous le format SMG (Simple Meta-Grammar), qui est celui utilisé sur ce wiki pour donner le source des classes.

Composants d'une méta-grammaire

Une méta-grammaire est organisée en une hiérarchie de classes, les classes servant à exprimer des contraintes sur une phénomène syntaxique (ou une facette de celui-ci).

class adverb {         
  ...         
 }

Une classe peut <span style="color:#0000CD;">hériter</span> des propriétés de classes parentes, ce qui permet de raffiner progressivement la description des phénomènes.        
 
class adverb_as_modifier {         
   <: adverb; %% this class inherits from the adverb class         
   ...         
}         
class adverb_as_verb_modifier {         
   <: adverb_as_modifier;         
   ....         
}

Une classe peut aussi requérir une fonctionnalité fournie par une autre classe, au travers d'un mécanisme de consommateur/producteur de ressources.

class adverb_as_modifier {         
   <: adverb;         
   - x_modifier; # require the functionality "modifier_of_something"         
   ....         
}         
class X_modifier {         
   + x_modifier; # provide the foncionality "modifier_of_something"         
   ...         
}

Ce mécanisme de gestion de ressources, puissant, vient en complément de l'héritage. En particulier, une ressource peut être consommée plusieurs fois par une classe dans des espaces de noms différents, ce qui n'est pas possible de faire par simple héritage.

class superlative_as_adj_mod {        
    <: superlative_as_mod;        
    %% require agreemnt for the determiner (le|la) and the adjective         
    - det::agreement; det=det::N;        
    - adj::agreement; adj=adj::N;        
    ...        
}        
class agreement {        
    + agreement;        
    %% provide agreement constraint between a node and its father        
    father(N).bot.gender = node(N).bot.gender;        
    ....        
}

Héritage et ressources forme l'ossature de la méta-grammaire (son organisation en terme de classes). La "chair" est fournie par le contenu des classes, portant sur des nœuds des arbres d'analyse, leurs décorations et des contraintes topologiques entre ces nœuds.

class very_simple_intransitive_verb {        
  %% declaration of nodes S, v, and Subject, with some decorations        
   node S: [cat: S, type: std];        
   node v: [cat: v, type: anchor, id: v];        
   node Subject: [cat: N2, type: subst, id: subject];        
   %% The subject precedes the verb        
   Subject < v;        
   %% The sentence node dominates the subject node        
   S >> Subject;        
   %% the sentence node also dominates the verb node, but indirectly        
   %% (to allow other nodes in-between)         
   S >>+ v;        
   ....        
}

À coté des contraintes topologiques (précédence, dominance, égalité), il est également possible d'exprimer des contraintes très riches portant sur les décorations des nœuds, par utilisation de variables ou au travers d'équations entre chemins conduisant d'une source à une valeur. La source d'un chemin est en général un nœud.

class very_simple_intransitive_verb {        
   ...        
   %% use of variable $number to force number agreement       
   node Subject: [cat: N2, type: subst, id: subject, top: [number: $number]];        
   node v : [cat:v, type: anchor, id: v, top: [number: $number]];        
}

class very_simple_intransitive_verb {        
   ...        
   %% alternative use of a path equation to force number agreement      
   node(Subject).top.number = node(v).top.number;        
}

La classe elle-même est le support d'une décoration, ancrée sur le mot clé desc, en particulier pour préparer l'hypertag qui peut associé à un arbre, ou pour gérer des traits globaux plutôt que spécifique à un nœud. Ce mot-clé desc peut être la source d'un chemin.

class very_simple_intransitive_verb {     
   ...     
   %% a non transitive verb has only one subject argument     
   desc.ht.arg0.function=value(subject);     
   desc.ht.arg1.function=value(-);     
   desc.ht.arg2.function=value(-);     
}     
%% alternative, using a full feature structure as value     
class very_simple_intransitive_verb {     
   ...     
   %% a non transitive verb has only one subject argument     
   desc.ht = value([arg0: [function: subject],      
                    arg1: [function: -],     
                    arg2: [function: -]     
                    ]);     
}

Il est également possible d'utiliser une variable (comme $ht) comme source d'un chemin.

class very_simple_intransitive_verb {     
   desc.ht = $ht;     
   ...     
   %% a non transitive verb has only one subject argument     
   $ht.arg1 = value(subject);     
   ....     
}

Les équations sont aussi exploitables pour exprimer des contraintes sur la présence ou l'absence d'un nœud. Une garde, positive ou négative, sur un nœud est ainsi une formule logique à base d'équations.

class very_simple_verb {     
  ...     
  %% a subject is present      
  %% if and only if the verb mood is not imperative or infinitive     
   Subject =>     
         node(v).top.mood = value(~imperative|infinitive);     
   ~ Subject =>     
         node(v).top.mood = value(imperative|infinitive);     
}

Les formules construites sur des équations entre chemins sont aussi utilisables pour exprimer des contraintes complexes, incluant entre autres des disjonctions, sans avoir à multiplier les classes.

class subordonate {    
...    
SubS +    
        node(SubS).top.mode = value(participle|gerundive),    
        node(SubS).top.inv = value(-),    
        node(SubS).top.extraction = value(-),    
        ( node(SubS).top.sat = value(-),    
          ( node(Foot).cat = value(coo)    
            |    
            node(Foot).cat = value(~coo),    
            node(Foot).top.number = node(SubS).bot.number,    
            node(Foot).top.person = node(SubS).bot.person,    
            node(Foot).top.gender = node(SubS).bot.gender    
            )    
          |    
          node(SubS).top.sat = value(ppart)    
          )    
        |    
        node(SubS).top.mode = value(~participle|gerundive),    
        node(SubS).top.sat = value(-)    
        ;    
}

À coté de ces éléments de base, qui suffisent déjà largement, il existe un mécanisme de raccourcis (macro) sur les valeurs des traits et sur les chemins

%% macro on value, for default agreement    
template @defaultagr = [person: 3, number: sg, gender: masc]    
%% macro on path    
path @function0 = .ht.arg0.function    
 
class csu {    
   ...    
   node(CS).bot = value(@defaultagr);    
}    
 
class very_simple_verb {    
   ...    
   desc.@function0 = value(subject);    
}

Lors de la phase de mise au point, il est possible de désactiver une classe et ses descendants

disable verb_categorization_passive

Comme toujours, le formalisme offre son lot de petits "trucs", bons à savoir. Ainsi, les nœuds ont une propriété type, avec quelques types spéciaux:

• alternative: pour un nœud dominant un ensemble de nœuds dont l'un seulement peut être utilisé lors d'une analyse
• sequence: pour un nœud interne dominant une séquence de fils, mais pour lequel on n'a pas de propriétés linguistiques particulières (pas de catégorie syntaxique par exemple)

class subject {  
     + subject;  
     node SubjectAlt: [type: alternative];  
     SubjectAlt >> CliticSubj; node CliticSubj: [cat: cln, type: coanchor];  
     SubjectAlt >> NominalSubj; node NominalSubj: [cat: N2, type: subst];  
     SubjectAlt >> SentSubj; node SentSubj: [cat: S, type: subst];  
     ...  
}

Ces types spéciaux seront en particulier utilisés pour produire des arbres factorisés.

On peut également indiquer qu'un noeud est optionnel (sans passer par une garde)

class pnoun {  
   ...  
   %% a proper noun may be preceded by an optional title  
   node Monsieur : [cat: title, type: coanchor, optional: yes];  
}

Il est également possible de rendre répétable un noeud, à la manière de l'opérateur "*" dans les expressions régulières (étoile de Kleene). Ceci est en essentiellement utilisé pour représenter la répétition dans les coordinations.

class simple_coord {  
   ...  
   node MiddleCoordSeq: [type: sequence, star: *];  
   node coord: [cat: coo, type: anchor];  
   node EndCoord: [cat: $cat];   
   MiddleCordSeq < coord;  
   coord < EndCoord;  
   MiddleCoordSeq >> MiddleCoord;  
   MiddleCoordSeq >> coma;  
   MiddleCoord < coma;  
   node MiddleCoord: [cat: $cat];  
   node comma: [lex: ",", type: lex];  
}

Phase de compilation

Production des arbres TAGs

Références

Pour décrire la grammaire d'une langue sous une forme exploitable par un ordinateur, il est nécessaire d'être extrêmement précis et d'utiliser un formalisme syntaxique adéquat.

Le plus simple et le plus connu de ceux-ci est certainement celui des grammaires hors-contexte (CFG, Context-Free Grammars), largement utilisées pour la description des langages de programmation.

Ainsi, la grammaire jouet suivante permet déjà de traiter une infinité de phrases simples, comme "Jean/np voit/v un/det homme/nc avec/prep un/det télescope/nc". Elle définit 8 productions pour les non-terminaux S (pour Sentence) ainsi que GN (Groupe Nominal), GP (Groupe Prépositionnel), et GV (Groupe Verbal).

S --> GN, GV.       
GN --> np.       
GN --> det, nc.       
GN --> GN, GP.       
GP --> prep, GN.       
GV --> v.       
GV --> v GN.       
GV --> GV GP.

Les CFG sont ainsi largement utilisées pour le traitement automatique des langues (TAL), mais essentiellement dans le cadre d'extraction automatique de grammaires à partir de corpus annotés syntaxiquement (treebanks). Elles sont par contre beaucoup moins adaptées pour le développement manuel de grammaires à large couverture. Outre leur manque d'expressivité pour traiter certains phénomènes, elles obligent également à multiplier le nombre de productions.

Au moins deux grandes approches ont été explorées pour promouvoir des formalismes syntaxiques de plus haut niveau, plus puissants (en terme de pouvoir d'expression) et mieux adaptés à l'écriture de larges grammaires (concision, ...).

• La première approche regroupe les grammaires d'unification comme LFG et HPSG, qui s'appuient sur l'utilisation de décorations au niveau des mots et des non-terminaux (via des structures de traits) pour pouvoir, au travers de l'opération d'unification, propager de l'information au sein de la phrase et gérer, par exemple, des phénomènes d'accord (entre un sujet et son verbe) ou des phénomènes d'extraction (pour une relative). Ainsi, une production gérant l'accord entre un nom et son déterminant, avec décorations, pourrait ressembler à

  GN{ nombre => N, genre => G } -->        
       det{ nombre => N, genre => G},        
       nc{ nombre => N, genre => G}.

• La seconde approche remplace la structure plate des productions (avec une simple liste de terminaux et non-terminaux) par des arbres. Ainsi, une représentation pour les verbes ditransitifs comme 'donner' pourrait représenter à

S(GN_subj,(GP(v,GN_obj,GP_objà)))

La seconde approche donne lieu à la notion de TSG (Tree Substitution Grammar) qui, en fait, n'étend pas la puissance expressive des CFG (on peut réécrire les arbres en productions CFG en introduisant nombre de non-terminaux intermédiaires). De plus, ces arbres sont quelque part trop fermés, dans le sens où on a parfois besoin d'introduire des éléments optionnels en leur sein, par exemple un adverbe comme dans "S(GN_subj(il) GV(v(donne) souvent GN(du pain) GP(aux canards)))". Ce constat est à la base de la notion de grammaires d'arbres adjoints (TAG) avec son opération d'adjonction. Celle-ci permet d'ouvrir un nœud d'un arbre en une partie haute (top) et basse (bot) et d'insérer entre ces deux parties le contenu d'un arbre dit auxiliaire. Ainsi, on peut avoir un arbre auxiliaire pour les adverbes qui vient s'insérer (s'adjoindre) au niveau d'un nœud GP.

Les TAG sont plus puissantes (en pouvoir d'expression) que les CFG tout en conservant de bonnes propriétés algorithmiques pour l'analyse. Elles font partie d'un continuum de formalismes dit faiblement dépendant du contexte qui allient à la fois cette puissance descriptive pour des phénomènes linguistiques et de bonnes propriétés algorithmiques.

Quelques références:

• [1]
• [2]
• [3]
• [4]
• [5]

Références

• [1]

Références

Crédit : Yoann Dupont

Installation de la chaîne

Prérequis

Configuration minimale recommandée :

• 2 coeurs
• 17 Go d'espace libre pour l'installation
• 4 Go de RAM

L'installation prend 2 à 4 heures, selon la puissance de l'ordinateur et la vitesse de la connexion à Internet.

Étapes

1. docker
2. alpi-docker
3. alternative : installation manuelle

1. Installer Docker

Pour installer Docker, il est recommandé de suivre les instructions de la documentation officielle :

• installation de Docker sur Linux (Ubuntu) : https://docs.docker.com/install/linux/docker-ce/ubuntu/
• installation de Docker sur Mac : https://docs.docker.com/docker-for-mac/
• installation de Docker sur Windows : https://docs.docker.com/docker-for-windows/

2. Utiliser Docker pour installer FRMG

Récupérez le dossier git frmg-docker et lancez l'installation :

git clone https://gitlab.inria.fr/???
cd frmg-docker/
docker build -t frmg .

Notes :

• Le dépôt git d'Aleda pèse 4Go, il est donc normal que l'installation prenne du temps à ce moment là.
• FRMG et LeFFF demandent un certain temps et une certaine quantité de RAM, faites bien attention à avoir environ 4Go de RAM disponible à ce moment.
• Cette méthode requière un accès au serveur.

3. Installation manuelle

Il est possible d'installer un à un les paquets, à partir d'alpi.

git clone https://gitlab.inria.fr/almanach/alpi.git
cd alpi
./alpi

Une fois l'installation terminée, il faut mettre à jour l'environnement afin d'accéder aux exécutables. En supposant que l'installation utilise le préfixe par défaut :

source ${HOME}/exportbuild/sbin/setenv.sh

Cette commande peut être ajoutée au fichier ".bashrc".

Afin de tester votre installation de FRMG, vous pouvez lancer la commande :

echo "Jean mange une pomme." | frmg_lexer | frmg_parser - -disamb -conll

Installation de l'environnement de développement

Paramètres Emacs

Le thème mg.el permet de colorer la syntaxe SMG.

Paramètres VSCode

Vous pouvez télécharger le module de coloration syntaxique pour VSCode à cette adresse : https://gitlab.inria.fr/mgkit/syntax_hightlighting_smg/-/tree/dev