class clitic_inverted_subject 
{
    %% Clitic inverted subject immediatly follow the first tensed verb (be it aux or modal)
    %% example: que mange-t-il, que n'a-t-il pas voulu mange, que veut-il manger
    %% it may only appear with wh-sentences
    %% it may be present with subject in canonical position
    %% example: quel livre Jean veut-il que Paul lise ?
    Infl >> clsubj_alt;
    %% Anchor may be v or aux
    Anchor < clsubj_alt;
    node clsubj_alt : [type: alternative];
    - clsubj_alt::agreement; clsubj_alt = clsubj_alt::N;
    node(clsubj_alt).top = node(clsubj_alt).bot;
    clsubj_alt >> clsubj;
    clsubj_alt >> clsubj_ilimp;
    clsubj_alt >> clsubj_il;
    clsubj < clsubj_ilimp;
    clsubj_ilimp < clsubj_il;
    node clsubj : [cat:cln, id: subject, type: coanchor, adj:no];
    - clsubj::agreement; clsubj = clsubj::N;
    node clsubj_ilimp : [cat:ilimp, id: impsubj, type: coanchor, adj:no];
    - clsubj_ilimp::agreement; clsubj_ilimp = clsubj_ilimp::N;
    %% ilimp is not yet perfect !
    node clsubj_il : [cat:cln, id: impsubj, type: coanchor, adj:no, lex: '-il'|'-t-il'];
    - clsubj_il::agreement; clsubj_il = clsubj_il::N;
    clsubj_alt =>
        node(Infl).bot.wh = value(+),
        node(Infl).bot.mode = value(~infinitive|participle|gerundive|imperative);
    %% in the case of impersonal, we can both a clsubj (for the impersonal) and a
    %% true postverbal subject
    %% example: existe-il une raison pour ne pas venir ?
    clsubj_alt =>
        node(Infl).bot.inv = value(cl),
        desc.dummy.impsubj = value(-|post)
        |
        node(Infl).bot.inv = value(~cl),
        desc.dummy.impsubj = value(post)
%        |
%        desc.dummy.impsubj = value(+)
        ;
    clsubj +
        desc.ht.imp = value(-),
        desc.dummy.impsubj = value(-)
        ;
    clsubj_ilimp +
        desc.ht.imp = value(+),
        desc.dummy.impsubj = value(post)
        ;
    clsubj_il +
        desc.ht.imp = value(+),
        desc.dummy.impsubj = value(post)
        ;
%    desc.ht.imp = desc.dummy.impsubj;
    ~ clsubj_alt =>
        node(Infl).bot.inv = value(~cl)
        |
        node(Infl).bot.inv = value(cl),
        node(Infl).bot.mode = value(infinitive|participle),
        node(V).top.mode = value(~infinitive|participle|gerundive|imperative)
        ;
}