class cnoun {
    %% Common nouns
    <: _cnoun;
    node Nc : [cat: nc];
    node(N2).bot.time = node(Nc).top.time;
    node(N2).bot.hum = node(Nc).top.hum;
    node(N2).bot.semtype = node(Nc).top.semtype;
    det =>
        node(N2).bot.sat = value(+);
    ~ det =>
        node(N2).bot.countable = value(-),
        node(N2).bot.wh = value(-),
        node(N2).bot.sat = value(-);
    %% add a node dominating N2 to anchor noun arguments
    %% in order to allow adjoining on the noun
    %% example: l'envie soudaine qu'il vienne
    node N2Root: [cat: N2, adj: no, type:std];
    node(N2Root).bot = node(N2).top;
    N2Root >> Arg0;
    N2Root >> N2;
    N2 < Arg0;
    node Arg0: [type: sequence];
    Arg0 =>
        desc.@kind0 = value(scomp),
        desc.@real0 = value(S),
        desc.@extracted0 = value(-),
        node(N2).bot.sat = value(+)
        ;
    ~ Arg0 =>
        desc.@kind0 = value(-),
        desc.@extracted0 = value(-),
        desc.@real0 = value(-)
        ;
    Arg0 >> csu;
    node csu:  [cat: que, adj: no, id: csu, type: coanchor ];
    Arg0 >> SArg;
    node SArg : [cat: S, id: xcomp, type: subst, top: [mode: ~participle|gerundive|imperative]];
    csu < SArg;
}