class _verb_or_aux {
    %% Verbs
    <: categories;
    node v: [];
    v = Anchor;
    node Infl:[cat:Infl, adjleft: atmostone]; Infl >> v;
    node V1: [cat:V1]; V1 >> Infl;
    node V:[cat:V, adjleft: atmostone]; V >> VMod;
    node VMod: [cat: VMod, id:vmod, bot: [position: post]]; node(VMod).top = node(VMod).bot;
    VMod >> V1;
%%    - VMod::vagreement; VMod = VMod::V;
    - V1VMod::agreement; V1=V1VMod::N;
    - V1::vagreement_ancestor; V1=V1::V; V=V1::Ancestor;
    - Infl::vagreement; Infl=Infl::V;
    %% this class used by aux, v and adj
    - cat_with_subcat;
    %% clr may inluence aux_req
%%    node(v).top.aux_req = node(Infl).bot.aux_req;
%%    node(v).top.diathesis = node(Infl).bot.diathesis;
    node(V1).bot.mode =  node(V1).top.mode;
    node(V1).bot.tense =  node(V1).top.tense;
    node(V1).bot.person =  node(V1).top.person;
    node(V1).bot.gender =  node(V1).top.gender;
    node(V1).bot.number =  node(V1).top.number;
    node(V1).bot.inv =  node(V1).top.inv;
    node(Infl).top.inv = node(V1).bot.inv;
    node(V1).top.inv = node(V).bot.inv;
    node(V).top.inv = node(S).bot.inv;
    node(V).bot.person =  node(V).top.person;
    node(V).bot.gender =  node(V).top.gender;
    node(V).bot.number =  node(V).top.number;
    node(V).bot.inv = node(V).top.inv;
    node(Infl).bot.inv = node(Infl).top.inv;
    node(v).top = node(v).bot;
    desc.extraction = value(-|rel|wh|cleft|adjx|topic|estceaux);
    %% participle verbs with aux_req=être agree with aux verbs
    %% special cases for polite vous and 'on'
    v +
        node(Infl).bot.number = node(Infl).top.number,
        node(Infl).bot.gender = node(Infl).top.gender
        |
        node(Infl).bot.mode = value(participle),
        node(Infl).bot.aux_req = value(être),
        ( desc.dummy.clr = value(-),
          (
              node(Infl).top.number = value(pl),
              node(Infl).top.person = value(2),
              node(Infl).bot.number = value(sg)
              |
              node(Infl).top.number = value(sg),
              node(Infl).top.person = value(3),
              node(Infl).top.gender = value(on)
           )
          |
          desc.dummy.clr = value(+)
          )
        |
        node(Infl).bot.mode = value(participle),
        node(Infl).bot.aux_req = value(~être)
        ;
    %% clitic inverted subject
    <: clitic_inverted_subject;
    node(Infl).bot.inv = value(-|cl|+);
    node(V1).bot.vlex = node(v).lex;
    node(V1).bot.vlex = node(V1).top.vlex;
    desc.dummy.arg0.xcomp_by_adj = $arg0::xcomp_by_adj;
    desc.dummy.arg1.xcomp_by_adj = $arg1::xcomp_by_adj;
    desc.dummy.arg2.xcomp_by_adj = $arg2::xcomp_by_adj;
}