class adv_subcat 
{
    %% we try to reuse the realisation of verbal arguments for adverbs
    + adv_subcat;
    Incise >> VModArg;
    Adv < VModArg;
    node VModArg : [id:vmod,cat:VMod,type:std, bot : [position: post]];
    node(VModArg).top = node(VModArg).bot;
    VModArg >> ArgGroup;
    desc.ht = value([arg0:[extracted: -,
                           pcas:-|à|de,
                           kind:prepobj|prepvcomp|prepscomp|-,
                           real: PP|-],
                     arg1:@emptyarg_fs,
                     arg2:@emptyarg_fs]);
    node ArgGroup : [type:alternative];
    $arg = desc.@arg0;
    VModArg =>
        $arg.kind = value(~-);
    ~ VModArg =>
        $arg.kind = value(-),
        $arg.real = value(-),
        $arg.pcas = value(-);
    node PP: [cat:PP,id:preparg];
    node(PP).top.pcas = $arg.pcas;
    ArgGroup >> PP;
    PP +
        $arg.real = value(PP),
        node(PP).top.real=value(N2|N),
        $arg.kind=value(prepobj);
    ArgGroup >> SComp;
    PP < SComp;
    node SArg : [cat: S];
    SComp +
        $arg.real = value(PP),
        $arg.pcas = value(à|de),
        $arg.pcas = node(prep).top.pcas;
    SArg +
        $arg.kind = value(prepscomp|prepvcomp)
        ;
    SArg +
        $arg.kind = value(prepscomp),
        node(SArg).top.mode = value(~infinitive)
        |
        $arg.kind = value(prepvcomp),
        node(SArg).top.mode = value(infinitive),
        node(SArg).top.control = value(~causative)
        ;
    node SComp : [cat:ArgComp, bot: [arg: $arg]];
    node prep: [cat: prep, id:prep, type: coanchor];
    SComp >> prep;
    node ce : [type:coanchor,lex:ce,cat:ce];
    SComp >> ce;
    prep < ce;
    ce =>
        $arg.kind = value(prepscomp);
    ~ ce =>
        $arg.kind = value(~prepscomp);
    node csu : [cat: que, adj: no, id: csu, type: coanchor ];
    SComp >> csu;
    csu =>
        $arg.kind = value(scomp|prepscomp);
    ~ csu =>
        $arg.kind = value(~scomp|prepscomp);
    ce < csu;
    SComp >> SArg;
    csu < SArg;
    node(SArg).top.mode = value(~participle|gerundive|imperative);
    node(SArg).id = value(xcomp);
}