class verb_mod_extraction_relative
{
    <: verb_mod_extraction;
    node XGroup: [type: alternative];
    node(S2).top.extraction = value(rel);
    node(S2).top.xarg = value([number: $number, gender: $gender, case: ~-]);
    node(S).top.wh = value(-);
    node(S).top.inv = value(~cl);
    node(S2).bot.xarg.case = node(prel_arg).bot.case;
    prel_arg +
        node(S2).bot.xarg.lex = node(prel_arg).lex;
    %% NOTE: infinitive relative for extracted modifiers are possible
    %% example: un endroit où dormir
    node(S).top.mode = value(conditional|subjonctive|indicative|adjective|infinitive);
    %% Relative sentence should not be saturated (by final punctuation)
    node(S).top.sat = value(-);
    node(S2).bot.sat = value(-);
    %% Realization as a relative pronoun
    node prel_arg : [cat:prel,id:prel,type:coanchor,bot: [case: ~nom|acc]];
    XGroup >> prel_arg;
    - prel_arg::agreement; prel_arg = prel_arg::N;
    %% Realization as a relative pronoun with a preposition
    XGroup >> prelPP;
    node prelPP : [type: sequence];
    prelPP >> prep;
    prelPP >> prel;
    prep < prel;
    node prep : [cat:prep,id:prep,type:coanchor,adj:no,bot: [pcas: ~-]];
    node prel : [cat:prel,id:prel,type:coanchor,adj:no,bot: [number: $number, gender: $gender]];
    prel_arg < prelPP;    
}