class number_as_det 
{
    %% Number as Determiner
    %% example: Deux enfants jouent
    %% example: Les deux  enfants jouent
    <: simple_categories;
    desc.ht = value([arg0: @emptyarg_fs,arg1: @emptyarg_fs,arg2: @emptyarg_fs]);
    node det : [cat: det, bot: [ wh: -, number: pl ]];
    node number : [cat: number]; number = Anchor;
    node det1 : [cat: det, type: coanchor, top: [ wh: -, number: pl]];
    det >> det1;
    det >> number;
    det >> range; node range: [type: sequence];
    range =>
        desc.dummy.range = value(+)
        ;
    ~ range =>
        desc.dummy.range = value(-)
        ;
    number < range;
    range >> prep; node prep: [cat: prep, type: coanchor, bot: [ pcas: à]];
    range >> number2; node number2: [cat: number, type: coanchor];
    prep < number2;
    det1 < number;
    node(number).top.gender = node(det).bot.gender;
    node(det).bot.def = node(det1).top.def;
    det1 =>
        node(det1).top.def = value(+)
        |
        node(det1).top.def = value(-),
        desc.dummy.range = value(+)
        ;
    ~ det1 =>
        node(det1).top.def = value(-) ;
}