class noun_mod_relative 
{
    %% we may have relative without verb
    %% example: il a trois enfant dont deux filles
    %% It seems to only occur with dont
    %% could maybe related to the notion of short_sentence
    - x_modifier;
    node(Root).bot = node(Foot).top;
    node Root : [cat: 'N2'];
    node(Foot).top = node(Root).bot;
    node Modifier : [type: sequence];
    Foot < Modifier;
    Modifier >> prep;
    Modifier >> prel;
    Modifier >> S;
    S >> N2;
    prep < prel;
    prel < S;
    node prep: [id: prep, cat: prep, type: coanchor, adj: no, bot: [pcas: parmi]];
    prep =>
        desc.dummy.parmis=value(+),
        node(prel).lex = value(lesquels|lesquelles)
        ;
    ~ prep =>
        desc.dummy.parmis=value(-),
        node(prel).bot.case=value(gen)
        ;
    node prel : [id: prel, cat: prel, type: coanchor, adj: no];
    node S : [id: 'SRel',
              cat: 'S',
              type: std,
              adj: no,
              bot: [mode: -, extraction: -, tense: -]];
    node N2 : [id: 'N2Rel', cat: 'N2', type: subst];
    desc.dependency = value('dep.relative');
}