class modal_verb
{
    %% Use auxiliary tree to handle modal verb (arg1=vcomp and no arg2)
    %% They adjoin on infinitive verbs
    %% *** there exists verbs with arg1=vcomp and arg2 not empty
    %% example: il lui affirme manger
    %% these verbs are not handled as modal verbs
    %% standard modal verb behave like vouloir
    %% example: il veut manger une pomme.
    %% we also add aller as a modal verb for progressive aspect, introducing a
    %% gerundive verb
    %% example: les recettes iront s'amenuisant.
    <: _verb;
    node(v).cat = value(v);
    %% No materialization of nodes S and S2
    %% Root is V;
    %% S=S2;
    %% node(S).bot.sat = value(-);
    - shallow_auxiliary;
    %% To get chaining adj even with TIG, we had a node V below Root
    %% and block adj on Root
    Root >> V;
    node(Root).bot.Vadj = value(-);
    node(Foot).top.Vadj = value(+);
    node(Root).cat = value(V);
    node(Root).adj = value(no);
    node(V).top = node(Root).bot;
    V < Foot;
    desc.extraction = value(-);
    desc.@extracted0 = value(-);
    desc.@extracted1 = value(-);
    desc.@extracted2 = value(-);
    node(Foot).top.mode = value(infinitive|gerundive);
    %% inherit from anchoring verb
    %% anchoring verb can not be participle
    node(Infl).top.mode = value(~participle);
    %% but share subject with adjoined verb
    node(Root).bot.number = node(Foot).top.number;
    node(Root).bot.gender = node(Foot).top.gender;
    node(Root).bot.person = node(Foot).top.person;
    desc.ht.arg0 = value([kind: subj, real: -, pcas: -]);
    v +
        node(Foot).top.mode = value(infinitive),
        desc.ht.arg1 = value([kind:vcomp, real: S, pcas: -, function: obj])
        |
        node(Foot).top.mode = value(gerundive),
        desc.ht.arg1 = value([kind:vcompprog, real: S, pcas: -, function: obl])
        ;
    desc.ht.arg2 = value(@emptyarg_fs);
    desc.ht.arg2.function = value(-);
    desc.ht.ctrsubj =  value(suj);
    %% Can only be used with active voice
    desc.ht.diathesis = value(active);
    %% No reflexive pronouns
    desc.ht.refl = value(-);
    node(Foot).bot.inv = node(V1).bot.inv;
    %% que for negation of vcomp
    %% example: il ne veut que dormir
    <: que_as_advneg; Sentence = Root; Arg = Root; Negated = Foot;
    V < advque;
    desc.dependency = value(modal);
}