class prep {
    %% Prepositions
    %% may introduce NP, S+infinitive, pronoun or ce que+S, simple nc or adj
    <: simple_categories;
    desc.@real0 = node(PP).top.real;
    desc.@real0 = value(N2|S|CS|pri|prel|adj|N|adv|-);
    PP >> Group;
    PP >> VMod;
    node VMod: [cat: vmodprep, adjright: atmostone, type: std];
    node(VMod).top = node(VMod).bot;
    node(VMod).bot.pcas = node(prep).bot.pcas;
    VMod >> prep;
    VMod < Group;
    node PP : [cat: PP];
    node Group : [type: alternative];
    Group =>
        desc.@kind0 = value(~ -);
    ~ Group =>
        desc.@kind0 = value(-),
        desc.@real0 = value(-);
    node prep : [cat: prep, adjright: atmostone, bot: [pcas: ~-]]; prep = Anchor;
    desc.ht = value([arg0:[extracted: -,
                           pcas:-,
                           kind:obj|acomp|vcomp|scomp|sadv|-],
                     arg1:@emptyarg_fs,
                     arg2:@emptyarg_fs]);
    node(PP).bot.pcas =node(prep).top.pcas;
    %% Prepositions introducing a nominal phrase or a pronoun or some
    %% unsaturated N2
    Group >> N2;
    node N2 : [cat: N2];
    N2 +
        desc.@kind0 = value(obj),
        node(N2).top.wh = node(PP).top.wh;
    N2 +
        desc.@real0 = value(N2);
        /*
    N2 +
        node(N2).top.sat = value(+),
        desc.@real0 = value(N2)
        |
        node(N2).top.sat = value(-),
        desc.@real0 = value(N)
        ;
        */
    %% Prepositions introducing an infinitive sentence
    %% they can only be introduced by à and de
    %% WARNING: should revise the list of possible prep (pour après, avant, avant_de, ..?)
    %% but maybe some confusion between prep/csu
    Group >> S;
    node S : [cat: S, top: [mode: infinitive, sat: -, extraction: -, control: ~causative]];
    S +
        desc.@kind0 = value(vcomp),
        desc.@real0 = value(S),
        node(PP).top.wh = value(-);
    N2 < S;
    %% Prepositions introducing a pri
    %% example: à qui tu  penses
    %% This case is handled by N2
%    Group >> pri;
%    node pri: [cat: pri,type:coanchor,adj:no];
%    pri +
%        desc.@real0 = value(pri),
%        desc.@kind0 = value(obj),
%        node(PP).top.wh = value(+);
%    S < pri;
    %% Prepositions introducing a wh-sentence
    %% example: j'ai réussi à ce qu'il vienne
    %% they can only be introduced by a and de
    %% WARNING: they may confused with relative construction: scomp-extraction
    %% je pense qu'il dit qu'il vient => je pense à ce qu'il dit
% handled by verb subcat     
%     Group >> CSGroup;
%     CSGroup >> CS;
%     CSGroup >> ce;
%     node CSGroup : [type: sequence];
%     node CS : [cat: CS, type: subst, top: [que: que]];
%     node ce : [type:coanchor,lex:ce, cat: ce, id:ce ];
%     CSGroup +
%         desc.@kind0 = value(scomp),
%         desc.@real0 = value(CS);
%     ce < CS;
% %%    pri < CSGroup;
%     S < CSGroup;
    %% prepositions introducing an adjP
    Group >> adjP;
    node adjP : [type: subst, cat: adjP];
    adjP +
        desc.@kind0 = value(acomp),
        desc.@real0 = value(adj);
%    CSGroup < adjP;
    S < adjP;
    %% prepositions introducing an adv
    Group >> adv;
    node adv : [type: coanchor, cat: adv, bot: [adv_kind: ~ très]];
    adjP < adv;
    adv +
        desc.@kind0 = value(sadv),
        desc.@real0 = value(adv);
    %% prepositions introducing a PP
    %% example: je pars de chez mon frère.
    %% example: Des contrats ont été signés dès avant le lancement de la production
    %% example: je pense aux évenements d'il y a un mois 
    Group >> PPchez;
    node PPchez : [type: subst, cat: PP, id: PP, bot: [ real: N2|adv, pcas: chez|loc]];
    adv < PPchez;
    PPchez +
        desc.@real0 = value(N2)
%        node(prep).bot.pcas = value(loc|de)
        ;
}