class collect_real_subject 
{
    <: _collect_real_subject;
    $arg.extracted = value(~cleft|topic);
    S >> VSubj;
    VSubj =>
        desc.ht.imp = value(-),
        desc.extraction = value(~topic)
        ;
    %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    %% Impersonnal Subject
    VSubj < imp_subj_alt;
    S >> imp_subj_alt;
    imp_subj_alt < V;
    <: impersonal_subject;
    %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    %% ça subject, redundant with a true subject
    %% example: les chats ça mange les souris
    %% example: ça ça serait vraiment euh sensationnel
    %% example: La moto ça lui plait aussi .
    S >> çasubj;
    imp_subj_alt < çasubj;
    çasubj < V;
    node çasubj : [cat: pro, id: subject, lex: ça|cela|ce, type: coanchor];
    çasubj =>
        desc.dummy.çasubj = value(+),
        desc.extraction = value(-),
        desc.dummy.presubj = value(+),
        $arg.real = value(~cln)
        ;
    ~ çasubj =>
        desc.dummy.çasubj = value(-)
        ;
    %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    %% Post Verbal Subject
    %% (in first approximation) may only occur for sentence with some extraction
    %% but not for an extracted subject
    %% May also occur for impersonal construction
    %% example: il se raconte une rumeur
    %% example: il se raconte qu'il vient
    %% 'une rumeur' and 'qu'll vient' may be seen as the deep semantic subject
    %% while 'il' is just a surface impersonal subject
    V >> postsubj;
    VMod < postsubj;
    node postsubj : [id:vmod,cat:VMod,type:std, bot : [position: post]];
%%    node(VMod).top = node(postsubj).bot;
    postsubj >> postsubjGroup;
    node(postsubj).top = node(postsubj).bot;
    node postsubjGroup: [type: alternative,top:[real:N2|S|CS|PP]];
    node(postsubjGroup).top = node(postsubjGroup).bot;
    %%    - postsubj::agreement; postsubj = postsubj::N;
    postsubj =>
        desc.dummy.presubj = value(-),
        $arg.extracted = value(-),
        $arg.real = node(postsubjGroup).top.real;
    %% A post-verbal subject is only possible for finite moods
    %% but for infinitive in the case of causative
    %% Causative sentence only possible for personal verbs
    %% example: Paul fait manger Marie
    %% example: Paul fait manger une pomme à Marie
    %% example: Paut fait manger une pomme par Marie
    postsubj =>
        desc.short_sentence = value(-),
        node(V).top.mode = value(~infinitive|imperative|gerundive|participle),
        node(S).top.control = value(-)
        |
        desc.short_sentence = value(-),
        node(V).top.mode = value(infinitive),
        node(S).top.control = value(causative|control_with_postsubj),
        desc.ht.imp = value(-)
        |
        %% short sentence like 'finies les vacances'
        %% see class S_pseudo_passive_sentence
        desc.short_sentence = value(+),
        node(V).top.mode = value(participle),
        desc.@diathesis = value(passive)
        |
        %% passive participale
        %% example: étant donnée la situation, je préfère partir
        desc.short_sentence = value(-),
        node(V).top.mode = value(gerundive),
        desc.@diathesis = value(passive)
        % ,node(S).bot.sat = value(ppart)
        |
        %% short sentence like 'difficile de venir ce soir'
        %% see class S_pseudo_adj_sentence
        desc.short_sentence = value(+),
        node(v).cat = value(adj)
        ;
    %% A subject may be inverted if either
    %% - there is an extraction, not on the subject
    %%   example: le livre que veut lire Paul
    %% - there is no extraction, but the verb is non-transitive
    %%   Vient un moment ou il faut choisir
    %% - some impersonel constructions (deep subjects)
    %%   Il se propage des rumeurs
    %% no aggrement when deep subject for impersonals
    %% example: il se raconte des histoires
    postsubj =>
        desc.ht.imp = value(+),
        $arg.kind = value(subj) % rule out 'nosubj' (impersonal without a deep subject)
        |
        desc.ht.imp = value(-),
        node(Infl).bot.inv = value(+),
        $arg.real = value(N2),
        node(V).bot.number = node(postsubjGroup).top.number,
        node(V).bot.gender = node(postsubjGroup).top.gender,
        node(V).bot.person = node(postsubjGroup).top.person,
        (
            desc.extraction = value(~-|adjx)
            |
            desc.extraction = value(-),
            $arg2::arg.kind = value(-|prepobj),
            (
                desc.ht.diathesis=value(active),
                $arg1::arg.kind = value(-|prepobj)
                |
                desc.ht.diathesis=value(passive)
             )
         )
        ;
    ~ postsubj =>
        node(Infl).bot.inv = value(~+),
%        node(S).top.control = value(~control_with_postsubj),
        ( desc.dummy.presubj = value(+)
          |
          desc.dummy.presubj = value(-),
          node(Infl).bot.inv = value(cl),
          $arg.real = value(cln)
          |
          desc.extraction = value(rel|wh),
          $arg.kind=value(subj)
          |
          $arg.real = value(-)
          )
        ;
    postsubj >> causative_prep;
    node causative_prep: [type: coanchor, id: causative_prep, cat:prep, bot: [pcas: par|à]];
    causative_prep < postsubjGroup;
    causative_prep =>
        node(v).cat = value(~adj),
        node(S).bot.control = value(causative)
        ;
    causative_prep =>
        node(causative_prep).bot.pcas = value(à),
        desc.ht.arg1.pcas = value(~à),
        desc.ht.arg2.pcas = value(~à)
        |
        node(causative_prep).bot.pcas = value(par),
        desc.ht.arg1.pcas = value(~par),
        desc.ht.arg2.pcas = value(~par)
        ;
    ~ causative_prep =>
        node(S).bot.control = value(~causative)
        |
        desc.ht.arg1.kind = value(-),
        desc.ht.arg2.kind = value(-)
        ;
    %% example: il se raconte des histoires
    - post_noun::true_subject;
    node post_noun::Subject : [cat:N2,type:subst,top:[wh:-,sat:+, case: nom]];
    post_noun::SubjectGroup = postsubjGroup;
%%    post_noun::Subject +
%%        node(postsubj).bot.cat = value(csu|S|adv)
%%        ;
    %% example: il se raconte qu'il ne vient plus
    - post_s::true_subject;
    node post_s::Subject : [cat:CS, type:subst, top: [que: que]];
    post_s::SubjectGroup = postsubjGroup;
    post_noun::Subject < post_s::Subject;
    post_s::Subject +
        node(V).top.mode = value(~subjonctive)
        ;
%%        node(postsubj).bot.cat = value(adv)
    %% example: 
    - post_v::true_subject;
    node post_v::Subject : [cat:S,
                            type:subst,
                            top:[mode: infinitive,
                                 sat: -,
                                 extraction: -,
                                 control: ~causative ]];
    post_v::SubjectGroup = postsubjGroup;
    post_s::Subject < post_v::Subject;
%     post_v::Subject +
%         node(postsubj).bot.cat = value(adv)
%         ;
    %% example: il lui arrive de courir vite
    - post_PP::true_subject;
    node post_PP::Subject : [cat:PP,type:subst,top:[real: S, pcas: de]];
    post_PP::SubjectGroup = postsubjGroup;
    post_v::Subject < post_PP::Subject;
%     post_PP::Subject +
%         node(postsubj).bot.cat = value(adv)
%         ;
}